Deploying Managed Kubernetes cluster with Terraform

terraform {
  required_providers {
    upcloud = {
      source  = "UpCloudLtd/upcloud"
      version = "~> 5.47"
    }
    local = {
      source  = "hashicorp/local"
      version = "~> 2.5"
    }
  }
}

# The UpCloud provider reads your API token from the UPCLOUD_TOKEN environment variable
provider "upcloud" {}

export UPCLOUD_TOKEN=ucat_Your_API_Token

variable "basename" {
  default     = "uks-cluster-example"
  description = "Basename to use when naming resources created by this configuration."
  type        = string
}

variable "zone" {
  default     = "de-fra1"
  description = "UpCloud zone for resource provisioning."
  type        = string
}

variable "store_kubeconfig" {
  default     = true
  description = "If set to `true`, store kubeconfig as a file with `local_file` to module path."
  type        = bool
}

variable "ip_network_range" {
  default     = "172.16.1.0/24"
  description = "CIDR range used by the cluster SDN network."
  type        = string
}

# Create a router for your network
resource "upcloud_router" "example" {
  name = "${var.basename}-router"
}

# Create a network for your cluster
resource "upcloud_network" "example" {
  name = "${var.basename}-net"
  zone = var.zone

  ip_network {
    address = var.ip_network_range
    dhcp    = true
    family  = "IPv4"
  }

  # If router is omitted here, UpCloud Kubernetes Service will add a router to this network automatically. In Terraform, we recommend defining the router explicitly to avoid Terraform trying to detach the automatically created router which is not recognized by Terraform.
  router = upcloud_router.example.id
  # If you do not explicitly set the router, you'll need to ignore changes to it. Otherwise, Terraform will attempt to detach the router on subsequent applies.
  # lifecycle {
  #   ignore_changes = [router]
  # }
}

# Create a cluster
resource "upcloud_kubernetes_cluster" "example" {
  name                    = "${var.basename}-cluster"
  network                 = upcloud_network.example.id
  zone                    = var.zone
  plan                    = "dev-md"
  control_plane_ip_filter = ["0.0.0.0/0"]
}

# Create a node group for your cluster
# Node group is a group of worker nodes that are created based on the same template
# You can have multiple node groups with different configurations in your cluster
resource "upcloud_kubernetes_node_group" "group" {
  name = "medium"

  // All nodes in this group will be joined to this cluster
  cluster = upcloud_kubernetes_cluster.example.id

  // The amount of created nodes (servers)
  node_count = 2

  // Plan for each node; you can list the available plans with the UpCloud CLI (`upctl server plans`)
  plan = "PREMIUM-2xCPU-4GB"

  // With `anti_affinity` set to true, UKS will attempt to deploy nodes in this group to different compute hosts
  anti_affinity = true

  // Each node in this group will have the following labels
  labels = {
    managedBy = "terraform"
    project   = "uks-instructions"
  }

  // If uncommented, each node in this group will have this taint
  # taint {
  #   effect = "NoExecute"
  #   key    = "key"
  #   value  = "value"
  # }

  // Each node in this group will have keys defined in this list configured as authorized keys (for "debian" user)
  ssh_keys = []
}

data "upcloud_kubernetes_cluster" "example" {
  id = upcloud_kubernetes_cluster.example.id
}

# With `hashicorp/local` Terraform provider one can output the kubeconfig to a file. The file can be easily
# used to configure `kubectl` or any other Kubernetes client.
resource "local_file" "kubeconfig" {
  count = var.store_kubeconfig ? 1 : 0

  content  = data.upcloud_kubernetes_cluster.example.kubeconfig
  filename = "${path.module}/kubeconfig.yml"
}

output "cluster_id" {
  value = upcloud_kubernetes_cluster.example.id
}

terraform init

terraform plan

terraform apply

export KUBECONFIG=$PWD/kubeconfig.yml

kubectl get nodes

terraform destroy